Synchronize your HP 100/200LX palmtop PIM data and e-mail to your REX-3 organizer
last updated:
Contents of this page:
Introduction:
If you own a REX-3 organizer (these little PC-card sized read-only organizers by
Franklin, former Rolodex, also sometimes called REX-3000)
and an HP palmtop, you may wish to synchonize the data of both devices.
This is possible, at least for the phone book and the note taker. The
appointment book of the Palmtop cannot be
transfered to the REX yet.
And unfortunately, only the REX-3 is supported, not its successors, the REX-5 or the REX-6.
The main work on this project is done by Christopher Lott, who wrote the software
needed to convert the phone book of the palmtop and single text files to the REX phone book and notes formats. And
by Mack Baggette who wrote the code to write the REX formatted data to
the REX card directly via he PCMCIA slot of the palmtop (the "device driver", so to speak).
I wrote a few filter programs which convert the GDBIO dump of the palmtop's note taker and Post/LX mailbox data
to the single text files
Chris' software needs to put them on the REX as memos.
Many thanks also to Andreas Garzotto (D&A Software) for the help on POST2REX!
Reqirements:
You need the following hard- and software if you want to synchronize your REX with the palmtop:
- a HP palmtop 100LX, 200LX or 700LX with at least 400-500 kB of free C: drive (you can't use a flash card in the PCMCIA slot,
because the slot will be occupied by the REX card during the synchronization process!), exact amount of needed disk space
depends on the size of your phone book and note taker file
- a REX-3 (256kB model)
- GDBIO, a software which dumps the database files of the palmtop to comma delimited files (CDF), you can
get GDBIO from the S.U.P.E.R. site
- HP2REX, the utilities by Chris Lott and Mack Baggette, which convert the data and write them to the REX,
download them here: ftp://ftp.alphabetatech.com/h2r091a.zip
- NDB2REX or POST2REX, my part of the project, which lets you easily put the palmtop's notes (NDB2REX) or
emails from a Post/LX mailbox file (POST2REX) on the REX-3.
Click here to download NDB2REX and here to download POST2REX.
- if you live in a country where you often use special characters like Umlauts in Germany or similar, I
recommend to use a text file search and replace utility, such as SED
(the stream editor)
to convert these characters, which the REX otherwise represents as
unreadable strange characters. An example for converting the German Umlauts will be given below.
You can download
SED from the S.U.P.E.R. site.
What can be synchronized?
Currently two groups of data are supported by Chris Lott's software:
Contacts (from the HP 200LX's phone book) and
text files, which are loaded into the memo part of the REX.
The latter opens a variety of possibilities: With special filters, you can convert nearly every
kind of stored information into ASCII text files.
For this purpose I wrote the programs NDB2REX and POST2REX.
NDB2REX converts a GDBIO dump of the palmtop's note taker
into ASCII text files (one file per note) and POST2REX does the same thing for emails which are stored in a
".I" inbox file of Post/LX (D&A software).
So you can e.g. load all your new email on the REX and read it there. Yet another even smaller email
reader than the palmtop ;-). This is especially useful if you receive lots of emails which you don't have to answer to,
like mailing lists or newsgroups.
The ZIP packages of my ...2REX packages contain the source codes, so please feel free to modify it to your needs
or write your own filters. I only ask you to notify me if you develop a new filter or improve one of mine. Maybe
I can offer that new or improved filter here besides the others.
By the way: It is also possible to put only one kind of data on the REX, either contacts or text files. So
if you have a huge phone book and don't need the notes, or if you want to read hundereds of emails but don't rely on
the contacts data base, you can leave out the steps described below for the kind of data you don't need.
Synchronizing guide:
The process of synchronizing sounds complicated, but once you have written a batch file to do the job, it's only
a single batch file call and everything is done.
First, download all above mentioned software and unpack it into a directory on the C: drive of your palmtop.
I recommend to read all documentation files, especially this one which comes with the H2R (HP2REX) software.
You need the following files (all other files can be deleted):
From the H2R package: all files
From the GDBIO package:
GDBIO.EXE
(GDBIO.DOC)
From the NDB2REX or POST2REX package: all files
From the SED package:
SED.EXE
Second, you have to prepare the MAP file for your REX contacts (this file is used by the converter software and holds
information about where in the REX contacts data base to map palmtop phone book entry fields).
This process is described in the README of the HP2REX software package under "CONTACTS Setup".
Now you can write the batch file which calls all needed programs. A simple example comes with HP2REX as H2R.BAT (but that
one only transfers the phone book).
Generally, the batch should do the following:
1. Convert the phone book to CDF format (GDBIO)
2. Convert the notes file to CDF format (GDBIO) (not needed if you don´t want notes on the REX)
3. (Replacing all special characters in the CDF files with standard ASCII characters (SED))
4. Creating the note files which can be used by HP2REX (from the notes CDF file with NDB2REX or from a Post/LX inbox file
with POST2REX)
5. Building the REX binary image file (HP2REX)
6. writing the image file to the REX (REXWR)
7. (cleaning up the directory by deleting the single note files (del command))
Comments:
1. This step is done by GDBIO. The command is
GDBIO c:\_dat\phone.pdb /n > rex.cdf (the map file must have the same base name as the CDF file, so it must
be named rex.map in this example; eventually adjust the path to your phone book file).
2. Again, GDBIO is used to dump the note taker file:
GDBIO c:\_dat\notes.ndb /n /x > notes.cdf (eventually adjust the path to your note taker file)
3. Use the command SED -f c:\utils\convert.sed rex.cdf > rex_conv.cdf
the file convert.sed is a sed script, which contains the sed commands for
the character conversions. For German umlauts, convert.sed could look as follows:
s/ä/ae/g
s/ö/oe/g
s/ü/ue/g
s/Ä/Ae/g
s/Ö/Oe/g
s/Ü/Ue/g
s/ß/ss/g
then delete the original rex.cdf and rename rex_conv.cdf back to rex.cdf.
4. NDB2REX / POST2REX creates one text file per note or email (*.RXN, ReX Note) and one text file containing the names of all note
RXN files (MDF file), the latter is used by HP2REX for converting the notes. So, call it as follows:
NDB2REX notes.cdf rex.mdf or
POST2REX c:\_dat\wwwlx\hplx-l.i rex.mdf /nq /n (for command line arguments of POST2REX please see README file in
the POST2REX ZIP package! They let you control if you copy only new or all messages
to the REX, and if quoted lines should be copied, too.)
5. Now, build the REX binary image file with
HP2REX rex -cm
(If you don't want to transfer any note files, leave away the m (memo), if you don't want to transfer the phone book,
leave away the c (contacts).
If you have used data from a flash card to prepare your image, i.e. if the REX card has not been inserted
before, you should add two line here:
echo Please insert the REX now!
pause
(you don't have to switch the palmtop off during the card swap, if your flash card is hot-swappable. The REX seems
to be hot-swappable without problems and most newer flash cards also should be. If yours isn't, you would get
data loss if you hot-swap the cards!!)
6. Write the image to the REX with
REXWR rex.bin
7. You now can (but don't have to) delete all the temporary files created from your palmtop files with
DEL *.RXN
DEL *.CDF
DEL *.MDF
DEL *.BIN
That's it.
Once you have prepared the batch, you only have to insert the REX-3 into the PCMCIA slot and call H2R.BAT.
Example batch file:
Here is my own batch file as an example. It converts phone book and note taker or
email folder. You can choose if you want notes or email at the beginning. "choice" from
a complete MS-DOS 5.0 installation is needed for that purpose.
@echo off
echo.
if exist notes.cdf del notes.cdf
choice /c:nm Transfer [N]otes or [M]ail to REX-Memo?
if errorlevel 2 goto mail
echo Dumping CDF file from note taker...
gdbio c:\_dat\notes.ndb /n /x > notes.cdf
goto phone
:mail
echo USING MAIL.I INBOX FILE, NEW MESSAGES, WITHOUT QUOTING
post2rex c:\_dat\wwwlx\mail.i rex.mdf /nq /n
:phone
echo Dumping CDF file from phone book...
gdbio c:\_dat\phone.pdb /n > rex.cdf
echo Converting special characters in CDF file...
sed -f c:\util\convert.sed rex.cdf > rex_conv.cdf
if errorlevel 1 goto sederror
del rex.cdf
ren rex_conv.cdf rex.cdf
goto sedok
:sederror
echo SED didn't work properly for some reason! Using unconverted file.
pause
:sedok
if exist notes.cdf ndb2rex notes.cdf rex.mdf
echo.
echo.
hp2rex rex -cm
echo insert REX now!
pause
echo writing to the REX...
rexwr rex.bin
echo Deleting temporary note files...
del *.rxn
del *.cdf
del *.mdf
del *.bin